FontDialogs.qml Example File

 /****************************************************************************
 **
 ** Copyright (C) 2016 The Qt Company Ltd.
 ** Contact: https://www.qt.io/licensing/
 **
 ** This file is part of the examples of the Qt Toolkit.
 **
 ** $QT_BEGIN_LICENSE:BSD$
 ** Commercial License Usage
 ** Licensees holding valid commercial Qt licenses may use this file in
 ** accordance with the commercial license agreement provided with the
 ** Software or, alternatively, in accordance with the terms contained in
 ** a written agreement between you and The Qt Company. For licensing terms
 ** and conditions see https://www.qt.io/terms-conditions. For further
 ** information use the contact form at https://www.qt.io/contact-us.
 **
 ** BSD License Usage
 ** Alternatively, you may use this file under the terms of the BSD license
 ** as follows:
 **
 ** "Redistribution and use in source and binary forms, with or without
 ** modification, are permitted provided that the following conditions are
 ** met:
 **   * Redistributions of source code must retain the above copyright
 **     notice, this list of conditions and the following disclaimer.
 **   * Redistributions in binary form must reproduce the above copyright
 **     notice, this list of conditions and the following disclaimer in
 **     the documentation and/or other materials provided with the
 **     distribution.
 **   * Neither the name of The Qt Company Ltd nor the names of its
 **     contributors may be used to endorse or promote products derived
 **     from this software without specific prior written permission.
 **
 **
 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
 **
 ** $QT_END_LICENSE$
 **
 ****************************************************************************/

 import QtQuick 2.2
 import QtQuick.Controls 1.2
 import QtQuick.Dialogs 1.1

 Item {
     width: 320
     height: 360
     SystemPalette { id: palette }
     clip: true

     FontDialog {
         id: fontDialog
         visible: fontDialogVisible.checked
         modality: fontDialogModal.checked ? Qt.WindowModal : Qt.NonModal
         scalableFonts: fontDialogScalableFonts.checked
         nonScalableFonts: fontDialogNonScalableFonts.checked
         monospacedFonts: fontDialogMonospacedFonts.checked
         proportionalFonts: fontDialogProportionalFonts.checked
         title: "Choose a font"
         font: Qt.font({ family: "Arial", pointSize: 24, weight: Font.Normal })
         currentFont: Qt.font({ family: "Arial", pointSize: 24, weight: Font.Normal })
         onCurrentFontChanged: { console.log("CurrentFontChanged: " + currentFont) }
         onAccepted: { console.log("Accepted: " + font) }
         onRejected: { console.log("Rejected") }
     }

     Column {
         id: optionsColumn
         anchors.fill: parent
         anchors.margins: 12
         spacing: 8
         Label {
             font.bold: true
             text: "Font dialog properties:"
         }
         CheckBox {
             id: fontDialogModal
             text: "Modal"
             checked: true
             Binding on checked { value: fontDialog.modality != Qt.NonModal }
         }
         CheckBox {
             id: fontDialogScalableFonts
             text: "Scalable fonts"
             Binding on checked { value: fontDialog.scalableFonts }
         }
         CheckBox {
             id: fontDialogNonScalableFonts
             text: "Non scalable fonts"
             Binding on checked { value: fontDialog.nonScalableFonts }
         }
         CheckBox {
             id: fontDialogMonospacedFonts
             text: "Monospaced fonts"
             Binding on checked { value: fontDialog.monospacedFonts }
         }
         CheckBox {
             id: fontDialogProportionalFonts
             text: "Proportional fonts"
             Binding on checked { value: fontDialog.proportionalFonts }
         }
         CheckBox {
             id: fontDialogVisible
             text: "Visible"
             Binding on checked { value: fontDialog.visible }
         }
         Label {
             text: "Current font:"
         }
         Label {
             id: fontLabel
             text: "<b>" + fontDialog.font.family + " - " + fontDialog.font.pointSize + "</b>"
             MouseArea {
                 anchors.fill: parent
                 onClicked: fontDialog.open()
             }
         }
     }

     Rectangle {
         anchors {
             left: parent.left
             right: parent.right
             bottom: parent.bottom
         }
         height: buttonRow.height * 1.2
         color: Qt.darker(palette.window, 1.1)
         border.color: Qt.darker(palette.window, 1.3)
         Row {
             id: buttonRow
             spacing: 6
             anchors.verticalCenter: parent.verticalCenter
             anchors.left: parent.left
             anchors.leftMargin: 12
             width: parent.width
             Button {
                 text: "Open"
                 anchors.verticalCenter: parent.verticalCenter
                 onClicked: fontDialog.open()
             }
             Button {
                 text: "Close"
                 anchors.verticalCenter: parent.verticalCenter
                 onClicked: fontDialog.close()
             }
             Button {
                 text: "set to default"
                 anchors.verticalCenter: parent.verticalCenter
                 onClicked: fontDialog.font = Qt.font({ family: "Arial", pointSize: 24, weight: Font.Normal })
             }
         }
     }
 }